File version

In article ,
Jolly Roger wrote:

> In article ,
> Loic wrote:
>
> > Any lead on how to get the version of a file. I mean, if i created a file
> > with an application (ex: photoshop) version 9 and later another file with a
> > version 10.
> > Can I know if the file was created with version 9 or 10 with AS ?
>
> Yep. This is rather simple.

In fact, it's not.

> Rather than just tell you the answer, I
> think I'll leave it as an exercise for you to find it though. That way
> hopefully you can learn how to help yourself more effectively. ; )
>
> Take a look in the Finder dictionary at the properties of the "Files"
> class. To view the dictionary of any application, choose File > Open
> Dictionary from the Script Editor menu bar.

And it turns out that this is no help at all to the OP.

The information the OP is looking for *may* be buried inside the PSD
file, but isn't guaranteed to be present as far as I can tell from
looking at the format spec. A recent PSD file I have has extensive runs
of XML in it including an element named xap:CreatorTool. Looking for
that is probably your best bet.

--
"Harry?" Ron's voice was a mere whisper. "Do you smell something ... burning?"
- Harry Potter and the Odor of the Phoenix
 >> Stay informed about: File version 

Jolly Roger wrote in


> In article ,
> Loic wrote:
>
>> Any lead on how to get the version of a file. I mean, if i created a
>> file with an application (ex: photoshop) version 9 and later another
>> file with a version 10.
>> Can I know if the file was created with version 9 or 10 with AS ?
>
> Yep. This is rather simple. Rather than just tell you the answer, I
> think I'll leave it as an exercise for you to find it though. That
> way hopefully you can learn how to help yourself more effectively. ;
> )
>
> Take a look in the Finder dictionary at the properties of the "Files"
> class. To view the dictionary of any application, choose File > Open
> Dictionary from the Script Editor menu bar.
>

Thanks for answer, I will have a look. Nevertheless, I viewed info
properties for file and it specifies "short version" that seems to be
what i am looking for. But when i try it on a file that i am interested
in, it returns nothing to this specific field.
Bye
Loic

--

....! > brain blackout
 >> Stay informed about: File version 

A recent PSD file I have has extensive
> runs of XML in it including an element named xap:CreatorTool. Looking
> for that is probably your best bet.
>
Hi thanks for the tip,
I will have a look as soon as possible and so throw my result.
Loic


--

....! > brain blackout
 >> Stay informed about: File version 

> Getting back to the OP: What are you really trying to accomplish? What
> value would it have to you, or what purpose does it serve in your
> larger task, to be able to know the name and version of the
> application that created the file? Perhaps there's another mechanism
> that will achieve the same goal.
>

Hope it helps understanding the whole process. A friend of mine is facing
a issue with Quark Xpress. He has files created with version 6 & version
7.
As the finder does not differenciate the version of the files, Xpress 6
users may accidentally try to open v7 files.
Trying to do so, the software just tell them that it was created with a
newer version and that it can't open the files.
So far no big deal. But after this, the file can't be opened anymore even
on a Xpress 7.

So, the main idea was to create a script that could explore the folders,
identify the version of the file, and move it to a specific subfolder.
V6 files to V6 subfolder of the parent folder
V7 files to V7 subfolder of the parent folder

At the end no more confusion between 6 & 7 files.
Thanks for help.
Loic
--

....! > brain blackout
 >> Stay informed about: File version 

Vous lisez mes messages et vous faites bien. Le 23/05/08 9:43, Loic a
écrit :

>
>> Getting back to the OP: What are you really trying to accomplish? What
>> value would it have to you, or what purpose does it serve in your
>> larger task, to be able to know the name and version of the
>> application that created the file? Perhaps there's another mechanism
>> that will achieve the same goal.
>>
>
> Hope it helps understanding the whole process. A friend of mine is facing
> a issue with Quark Xpress. He has files created with version 6 & version
> 7.
> As the finder does not differenciate the version of the files, Xpress 6
> users may accidentally try to open v7 files.
> Trying to do so, the software just tell them that it was created with a
> newer version and that it can't open the files.
> So far no big deal. But after this, the file can't be opened anymore even
> on a Xpress 7.
>
> So, the main idea was to create a script that could explore the folders,
> identify the version of the file, and move it to a specific subfolder.
> V6 files to V6 subfolder of the parent folder
> V7 files to V7 subfolder of the parent folder
>
> At the end no more confusion between 6 & 7 files.
> Thanks for help.
> Loic

Loïc,

I sent you at your private address a script (or ebtter said an application)
that sorts things out.
I myself did not write it unfortunately. It shall return a dialog showing
what version the file was last saved in, even PC or Mac.
Feel free to open it and learn more about it. Edit it to your own goals.

--
Jean-Marie

« On peut toujours rêver, c'est pas cher et c'est bon marché... » (Sttellla)
 >> Stay informed about: File version 

In article ,
Jean-Marie Schwartz wrote:

> Vous lisez mes messages et vous faites bien. Le 23/05/08 9:43, Loic a
> écrit :
>
> >> Getting back to the OP: What are you really trying to accomplish? What
> >> value would it have to you, or what purpose does it serve in your
> >> larger task, to be able to know the name and version of the
> >> application that created the file? Perhaps there's another mechanism
> >> that will achieve the same goal.
> >
> > Hope it helps understanding the whole process. A friend of mine is facing
> > a issue with Quark Xpress. He has files created with version 6 & version
> > 7.
> > As the finder does not differenciate the version of the files, Xpress 6
> > users may accidentally try to open v7 files.
> > Trying to do so, the software just tell them that it was created with a
> > newer version and that it can't open the files.
> > So far no big deal. But after this, the file can't be opened anymore even
> > on a Xpress 7.
> >
> > So, the main idea was to create a script that could explore the folders,
> > identify the version of the file, and move it to a specific subfolder.
> > V6 files to V6 subfolder of the parent folder
> > V7 files to V7 subfolder of the parent folder
> >
> > At the end no more confusion between 6 & 7 files.
>
> I sent you at your private address a script (or ebtter said an application)
> that sorts things out.
> I myself did not write it unfortunately. It shall return a dialog showing
> what version the file was last saved in, even PC or Mac.
> Feel free to open it and learn more about it. Edit it to your own goals.

Jean-Marie: Why not post the script here so that others may benefit from
it as well? Isn;t that the whole point of news groups??

--
Please send all responses to the relevant news group. E-mail sent to
this address may be devoured by my very hungry SPAM filter. I do not
read posts from Google Groups. Use a real news reader if you want me to
see your posts.

JR
 >> Stay informed about: File version 

Jean-Marie Schwartz wrote in


> Vous lisez mes messages et vous faites bien. Le 23/05/08 9:43, Loic a
> écrit :
>
>>
>>> Getting back to the OP: What are you really trying to accomplish?
>>> What value would it have to you, or what purpose does it serve in
>>> your larger task, to be able to know the name and version of the
>>> application that created the file? Perhaps there's another mechanism
>>> that will achieve the same goal.
>>>
>>
>> Hope it helps understanding the whole process. A friend of mine is
>> facing a issue with Quark Xpress. He has files created with version 6
>> & version 7.
>> As the finder does not differenciate the version of the files, Xpress
>> 6 users may accidentally try to open v7 files.
>> Trying to do so, the software just tell them that it was created with
>> a newer version and that it can't open the files.
>> So far no big deal. But after this, the file can't be opened anymore
>> even on a Xpress 7.
>>
>> So, the main idea was to create a script that could explore the
>> folders, identify the version of the file, and move it to a specific
>> subfolder. V6 files to V6 subfolder of the parent folder
>> V7 files to V7 subfolder of the parent folder
>>
>> At the end no more confusion between 6 & 7 files.
>> Thanks for help.
>> Loic
>
> Loïc,
>
> I sent you at your private address a script (or ebtter said an
> application) that sorts things out.

Thanks a lot Jean-Marie
Loic
PS : are you sure about mail, I think I indicated a junk mail.
Here is a good one loic at caldera.eu
--

....! > brain blackout
 >> Stay informed about: File version 

Vous lisez mes messages et vous faites bien. Le 23/05/08 15:17, Jolly Roger
a écrit :

> In article ,
> Jean-Marie Schwartz wrote:
>
>> Vous lisez mes messages et vous faites bien. Le 23/05/08 9:43, Loic a
>> écrit :
>>
>> I sent you at your private address a script (or ebtter said an application)
>> that sorts things out.
>> I myself did not write it unfortunately. It shall return a dialog showing
>> what version the file was last saved in, even PC or Mac.
>> Feel free to open it and learn more about it. Edit it to your own goals.
>
> Jean-Marie: Why not post the script here so that others may benefit from
> it as well? Isn;t that the whole point of news groups??

Here it is (I wasn't able to copy-paste from Script Editor...):

[code]
global biblio

on open fileList
set nDoc to count fileList
if nDoc > 1 then quickSort(fileList, 1, nDoc)
repeat with aDoc in fileList
set biblio to 0
set filePath to aDoc as string
if filePath ends with ":" then
display dialog "C¹était un dossier !

Il ne faut déposer que des fichiers
sur ce droplet." buttons "OK" default button 1 with icon 0
else
set fileInfo to (info for file filePath)
set docName to name of fileInfo
set fileCreator to ""
set fileType to ""
try
set fileCreator to file creator of fileInfo
end try
try
set fileType to file type of fileInfo
end try
if fileCreator = "XPR3" and fileType = "TEXT" then
set tagVers to getTagVers(filePath)
if tagVers is not 0 then
if tagVers is {0, 0} then
infTags0(docName)
else
set progVers to item 1 of tagVers
set platForm to item 2 of tagVers
infTags1(docName, progVers, platForm)
end if
else
infDict(docName)
end if
else if fileCreator = "ttxt" and fileType = "TEXT" then
set docVers to getVers(filePath)
if docVers = "Ce n¹est pas un document XPress." then
set tagVers to getTagVers(filePath)
if tagVers is not 0 then
if tagVers is {0, 0} then
infTags0(docName)
else
set progVers to item 1 of tagVers
set platForm to item 2 of tagVers
infTags2(docName, progVers, platForm)
end if
else
infDoc(filePath, fileType, docName, "Ce")
end if
else
infUser2(filePath, docName, docVers)
end if
else if fileCreator = "????" and fileType = "????" then
set tagVers to getTagVers(filePath)
if tagVers is not 0 then
if tagVers is {0, 0} then
infTags0(docName)
else
set progVers to item 1 of tagVers
set platForm to item 2 of tagVers
infTags3(filePath, docName, progVers, platForm)
end if
else
set docVers to getVers(filePath)
if docVers is not "0" then
infDoc(filePath, fileType, docName, docVers)
else
display dialog "Il y avait un problème lors
de la lecture du fichier." buttons "OK" default button 1 with icon 2
end if
end if
else
set docVers to getVers(filePath)
if docVers is not "0" then
infDoc(filePath, fileType, docName, docVers)
else
display dialog "Il y avait un problème lors
de la lecture du fichier." buttons "OK" default button 1 with icon 2
end if
end if
end if
end repeat
end open

on quickSort(a, L, R)
set i to L
set n to R
set aRef to item L of a as text
repeat while i < n
repeat while (aRef < item n of a) and (i < n)
set n to n - 1
end repeat
if n ‚ i then
set item i of a to item n of a
set i to i + 1
end if
repeat while (aRef > item i of a) and (i < n)
set i to i + 1
end repeat
if n ‚ i then
set item n of a to item i of a
set n to n - 1
end if
end repeat
set item n of a to aRef
if L < n then
quickSort(a, L, n - 1)
end if
if R > i then
quickSort(a, i + 1, R)
end if
return a
end quickSort

on getTagVers(filePath)
try
set tagsClue to read file filePath for 11
on error
return {0, 0}
end try
if tagsClue contains "7" then
set tagsClue to read file filePath for 24
set charList to {}
repeat with i from 1 to 24
set curChar to character i of tagsClue
set curCode to ASCII number of curChar
if curCode is greater than 45 and curCode is less than 127 then
set end of charList to curChar
end if
end repeat
set tagsClue to charList as string
end if
if tagsClue starts with "<" then
set filterVers to text 3 thru 6 of tagsClue
set platVers to text 9 thru 10 of tagsClue
if filterVers = "7.10" then
set progVers to "7.1"
else if filterVers = "7.00" then
set progVers to "7.0"
else if filterVers = "6.50" then
set progVers to "6.5"
else if filterVers = "6.10" then
set progVers to "6.1"
else if filterVers = "4.00" then
set progVers to "6.0"
else if filterVers = "3.00" then
set progVers to "5.0x"
else if filterVers = "2.05" then
set progVers to "4.11"
else if filterVers = "2.03" then
set progVers to "4.04"
else if filterVers = "2.02" then
set progVers to "4.02 oder 4.03"
else if filterVers = "2.00" then
set progVers to "4.0"
else if filterVers = "1.70" then
set progVers to "3.3x"
else if filterVers = "1.60" then
set progVers to "3.2x"
else if filterVers = "1.50" then
set progVers to "3.1"
else
set progVers to "inconnu"
end if
if platVers = "e0" then
if filterVers starts with "7" then
set platForm to "Mac Roman (x-mac-roman)"
else
set platForm to "Macintosh"
end if
else if platVers = "e1" then
if filterVers starts with "7" then
set platForm to "Windows Latin (windows-1252)"
else
set platForm to "Windows"
end if
else if platVers = "e2" then
if filterVers starts with "7" then
set platForm to "Western (iso-8859-1)"
else
set platForm to "Latin 1"
end if
else if platVers = "e3" then
set platForm to "Japanese (shift_jis)"
else if platVers = "e4" then
set platForm to "Korean (EUC-KR)"
else if platVers = "e6" then
set platForm to "Chinese Trad. (big 5)"
else if platVers = "e6" then
set platForm to "Chinese Simp. (gb2312)"
else if platVers = "e8" then
set platForm to "Unicode (UTF-16)"
else if platVers = "e9" then
set platForm to "Unicode (UTF-"
else
set platForm to "inconnu"
end if
return {progVers, platForm}
else
return 0
end if
end getTagVers

on infTags0(docName)
display dialog "Il y avait un problème lors
de la lecture de l¹info du fichier
« " & docName & ". »

Désolé." buttons "OK" default button 1 with icon 2
end infTags0

on infTags1(docName, progVers, platForm)
if progVers is not 0 then
display dialog "Le fichier balises XPress
« " & docName & " »

a probablement été exporté depuis
QuarkXPress v." & progVers & "
[ " & platForm & " ]" buttons "OK" default button 1 with icon 2
else
display dialog "Le fichier balises XPress
« " & docName & " »

ne contient pas de numéro de version
du filtre XPress Tags." buttons "OK" default button 1 with icon 2
end if
end infTags1

on infTags2(docName, progVers, platForm)
if progVers is not 0 then
display dialog "Le fichier balises XPress
« " & docName & " »

a probablement été préparé pour
QuarkXPress v." & progVers & "
[ " & platForm & " ]" buttons "OK" default button 1 with icon 2
else
display dialog "Le fichier balises XPress
« " & docName & " »

ne contient pas de numéro de version
du filtre XPress Tags." buttons "OK" default button 1 with icon 2
end if
end infTags2

on infTags3(filePath, docName, progVers, platForm)
set dResult to button returned of (display dialog "Le fichier balises
XPress
« " & docName & " »

a probablement été préparé pour
QuarkXPress v." & progVers & "
[ " & platForm & " ]

Mais le créateur et le type du fichier
doivent être rétablis, sinon on
ne peut pas l¹importer dans XPress." buttons {"Ne rien faire", "Rétablir"}
default button 2 with icon 2)
if dResult is "Rétablir" then
try
tell application "Finder" to set creator type of file filePath
to "XPR3"
end try
try
tell application "Finder" to set file type of file filePath to
"TEXT"
end try
else
return
end if
end infTags3

on infDict(docName)
display dialog "Le fichier
« " & docName & " »

pourrait être un dictionnaire auxiliaire
QuarkXPress." buttons "OK" default button 1 with icon 2
end infDict

on getVers(filePath)
try
set versionClue to read file filePath for 12
on error
return "0"
end try
if character 5 of versionClue = "ÿ" then set biblio to 1
if versionClue contains "MM" and versionClue contains "PR3" then
if versionClue ends with "?" then
return "QuarkXPress 3.x (Mac)"
else if versionClue ends with "A" then
return "QuarkXPress 4.x (Mac)"
else if versionClue ends with "B" then
return "QuarkXPress 5.x (Mac)"
else if versionClue ends with "C" then
return "QuarkXPress 6.x (Mac)"
else if versionClue ends with "D" then
return "QuarkXPress 7.x (Mac)"
else
return "inconnu (Mac)"
end if
else if versionClue contains "II" then
set testChar to character 11 of versionClue
if character 11 of versionClue = "?" then
return "QuarkXPress 3.x (Windows)"
else if character 11 of versionClue = "A" then
return "QuarkXPress 4.x (Windows)"
else if character 11 of versionClue = "B" then
return "QuarkXPress 5.x (Windows)"
else if character 11 of versionClue = "C" then
return "QuarkXPress 6.x (Windows)"
else if character 11 of versionClue = "D" then
return "QuarkXPress 7.x (Windows)"
else
return "inconnu (Windows)"
end if
else
return "Ce n¹est pas un document XPress."
end if
end getVers

on infDoc(filePath, fileType, docName, docVers)
if docVers starts with "Ce" then
infUser0(docName)
else
if fileType is not "" then
if docVers contains "6" or docVers contains "7" then
set okay to 1
if fileType = "XPRJ" then
set curDoc to "du projet"
else if fileType = "XPRT" then
set curDoc to "du gabarit"
else if fileType = "XLIB" then
set curDoc to "de la bibliothèque"
else
set okay to 0
infUser2(filePath, docName, docVers)
end if
else
set okay to 1
if fileType = "XDOC" then
set curDoc to "du document"
else if fileType = "XTMP" then
set curDoc to "du gabarit"
else if fileType = "XLIB" then
set curDoc to "de la bibliothèque"
else
set okay to 0
infUser2(filePath, docName, docVers)
end if
end if
else
set okay to 0
set curDoc to "du machin"
infUser1(curDoc, docName, docVers)
end if
if okay = 1 then
infUser1(curDoc, docName, docVers)
end if
end if
end infDoc

on infUser0(docName)
display dialog "Le document
« " & docName & " »

ne semble pas être un fichier XPress." buttons "OK" default button 1 with
icon 2
end infUser0

on infUser1(curDoc, docName, docVers)
display dialog "La version " & curDoc & "
« " & docName & " » :

" & docVers & "." buttons "OK" default button 1 with icon 1
end infUser1

on infUser2(filePath, docName, docVers)
if biblio = 1 then
set whatKind to "de la bibliothèque"
else
if docVers contains "6" or docVers contains "7" then
set whatKind to "du projet"
else
set whatKind to "du document"
end if
end if
set dResult to button returned of (display dialog "La version " &
whatKind & "
« " & docName & " » :

" & docVers & "

Mais le créateur et le type du fichier
doivent être rétablis, sinon on
ne peut pas l¹ouvrir avec XPress." buttons {"Ne rien faire", "Rétablir"}
default button 2 with icon 2)
if dResult is "Rétablir" then
try
tell application "Finder" to set creator type of file filePath
to "XPR3"
end try
if docVers contains "6" then
if biblio = 0 then
try
tell application "Finder" to set file type of file
filePath to "XPRJ"
end try
else
try
tell application "Finder" to set file type of file
filePath to "XLIB"
end try
end if
else
if biblio = 0 then
try
tell application "Finder" to set file type of file
filePath to "XDOC"
end try
else
try
tell application "Finder" to set file type of file
filePath to "XLIB"
end try
end if
end if
else
return
end if
end infUser2
[/code]

--
Jean-Marie

« Mi ricordo che un giorno... in mezzo a noi venne un tipo... che ogni cosa
pensava giusto e la fonte della vita era in lui disse una frase... mi rimase
impressa: "Alzati ...e cammina!"... » (Adriano Celentano, «Cammino»)
 >> Stay informed about: File version 

In article ,
Jean-Marie Schwartz wrote:

> [code]

BTW, this isn't a web forum - it's Usenet. Tags like [code] mean nothing
here. ; )

--
Please send all responses to the relevant news group. E-mail sent to
this address may be devoured by my very hungry SPAM filter. I do not
read posts from Google Groups. Use a real news reader if you want me to
see your posts.

JR
 >> Stay informed about: File version 

Vous lisez mes messages et vous faites bien. Le 23/05/08 14:39, Loic a
écrit :

> Jean-Marie Schwartz wrote in
>
>
>> Vous lisez mes messages et vous faites bien. Le 23/05/08 9:43, Loic a
>> écrit :
>>
>> Loïc,
>>
>> I sent you at your private address a script (or ebtter said an
>> application) that sorts things out.
>
> Thanks a lot Jean-Marie
> Loic
> PS : are you sure about mail, I think I indicated a junk mail.
> Here is a good one loic at caldera.eu
OK, sorry about it! I forgot about this one.
Resent to you.
--
Jean-Marie

« ¡Oyé pana! ¿Qué pasa por la calle?
‹ ¡Nada, no pasa nada! »
(«Guayaquil City», Mano Negra)
 >> Stay informed about: File version 

Vous lisez mes messages et vous faites bien. Le 26/05/08 18:39, Jolly Roger
a écrit :

> In article ,
> Jean-Marie Schwartz wrote:
>
>> [code]
>
> BTW, this isn't a web forum - it's Usenet. Tags like [code] mean nothing
> here. ; )
I was more expecting sth like "Thank you Jean-Marie for sharing that
marvellous script, even if you did not write it yourself".
But well...
--
Jean-Marie

« On peut toujours rêver, c'est pas cher et c'est bon marché... » (Sttellla)
 >> Stay informed about: File version 

In article ,
Jean-Marie Schwartz wrote:

> Vous lisez mes messages et vous faites bien. Le 26/05/08 18:39, Jolly Roger
> a écrit :
>
> > In article ,
> > Jean-Marie Schwartz wrote:
> >
> >> [code]
> >
> > BTW, this isn't a web forum - it's Usenet. Tags like [code] mean nothing
> > here. ; )
> I was more expecting sth like "Thank you Jean-Marie for sharing that
> marvellous script, even if you did not write it yourself".
> But well...

While he's sometimes a bit terse, I don't think JR was criticizing so
much as trying to offer a helpful tip.

G

--
"Harry?" Ron's voice was a mere whisper. "Do you smell something ... burning?"
- Harry Potter and the Odor of the Phoenix
 >> Stay informed about: File version 

In article ,
Jean-Marie Schwartz wrote:

> Vous lisez mes messages et vous faites bien. Le 26/05/08 18:39, Jolly Roger
> a écrit :
>
> > In article ,
> > Jean-Marie Schwartz wrote:
> >
> >> [code]
> >
> > BTW, this isn't a web forum - it's Usenet. Tags like [code] mean nothing
> > here. ; )
>
> I was more expecting sth like "Thank you Jean-Marie for sharing that
> marvellous script, even if you did not write it yourself".
> But well...

Thank you for sharing - I do appreciate it. And I'm sure others
appreciate it as well.

This still isn't a web forum though, and [] tags won't do anything as a
result.

Just trying to help...

--
Please send all responses to the relevant news group. E-mail sent to
this address may be devoured by my very hungry SPAM filter. I do not
read posts from Google Groups. Use a real news reader if you want me to
see your posts.

JR
 >> Stay informed about: File version